# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/libsynce/libsynce-0.15.1.ebuild,v 1.3 2012/05/04 18:35:55 jdhore Exp $

EAPI=4

PYTHON_DEPEND="python? 2:2.7"

inherit eutils python

DESCRIPTION="Base libraries, including RAPI protocol, tools and dccm daemon"
HOMEPAGE="http://sourceforge.net/projects/synce/"
SRC_URI="mirror://sourceforge/synce/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="bluetooth +dbus python static-libs +udev"

# AC_PATH_PROG -> pppd -> net-dialup/ppp
# AC_PATH_PROG -> ifconfig -> sys-apps/net-tools
RDEPEND=">=dev-libs/glib-2.22
	!dev-libs/libsynce
	net-dialup/ppp
	sys-apps/net-tools
	dbus? ( >=dev-libs/dbus-glib-0.98 )
	python? ( >=dev-python/pyrex-0.9.6 )
	udev? ( || ( >=sys-fs/udev-171-r6[gudev] <sys-fs/udev-171[extras] ) )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"
REQUIRED_USE="bluetooth? ( udev )
	udev? ( dbus )"

pkg_setup() {
	if use python; then
		python_set_active_version 2
		python_pkg_setup
	fi
}

src_prepare() {
	# AC_PATH_PROG -> dhclient ->
	sed -i -e 's:dhclient:true:' configure || die
}

src_configure() {
	# Enable ODCCM support from USE="dbus" because it has no other dependencies
	econf \
		$(use_enable static-libs static) \
		--enable-dccm-file-support \
		$(use_enable dbus odccm-support) \
		--disable-hal-support \
		$(use_enable udev udev-support) \
		$(use_enable bluetooth bluetooth-support) \
		$(use_enable python python-bindings)
}

src_install() {
	emake DESTDIR="${D}" install

	dodoc BUGS ChangeLog README* TODO
	newdoc bluetooth/README README.bluetooth

	prune_libtool_files
}